【板子申请】Ai-M61-32S开发环境搭建过程——win10虚拟机附环境变量设置脚本

板子申请专区 · 2023-11-17 12:21:48

本帖最后由 sonataa 于 2023-11-17 12:26 编辑

官网帖子教程非常细致
个人建议还是在虚拟机中运行
全新系统安装，可以有效排除干扰
跟着一步步走搭建完成

QQ截图20231117113816.png

附上安装完成后和导入后的图片
唯一的麻烦点的就是系统环境变量的设置
抽空写一个bat脚本
在AiPi-Open-Kits文件夹下新建文本文档
然后复制进去后后缀改成bat
然后鼠标右键用管理员身份运行即可

@echo off
::系统变量所在位置：`HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Session Manager\Environment`
set MACHINEregpath=HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment
:: 获取脚本所在目录
set "SCRIPT_DIR=%~dp0"
:: 设置路径变量
set "MAKE_PATH=%SCRIPT_DIR%aithinker_Ai-M6X_SDK\tools\make"
set "TOOLCHAIN_PATH=%SCRIPT_DIR%aithinker_Ai-M6X_SDK\toolchain_gcc_t-head_windows\bin"
set "NINJA_PATH=%SCRIPT_DIR%aithinker_Ai-M6X_SDK\tools\ninja"
color 17
echo.
echo =====================================================
echo 小安派环境变量设置
echo =====================================================
echo.
set /P EN=请用系统管理员运行按回车键确认设置开始!
:: 检查目录是否存在
if not exist "%MAKE_PATH%" (
echo 指定的路径不存在：%MAKE_PATH%
pause
exit /b
)
if not exist "%TOOLCHAIN_PATH%" (
echo 指定的路径不存在：%TOOLCHAIN_PATH%
pause
exit /b
)
if not exist "%NINJA_PATH%" (
echo 指定的路径不存在：%NINJA_PATH%
pause
exit /b
)
for /f "tokens=2,* delims= " %%a in ('reg query "%MACHINEregpath%" /v "path" 2^>nul') do (
set myValue=%%b
)
if not "%SCRIPT_DIR%"=="" (
echo %myValue% | find /i "%SCRIPT_DIR%" > nul
if errorlevel 1 (
echo 开始更新
) else (
echo 环境变量中已包含该目录，退出
pause
exit /b
)
) else (
echo empty.
exit /b
)
reg add "%MACHINEregpath%" /v "Path" /t REG_EXPAND_SZ /d "%MAKE_PATH%;%myValue%;%TOOLCHAIN_PATH%;%NINJA_PATH%;" /f
echo ***********环境变量设置结束! ***********
echo.
echo 按任意键退出，请自行重启!
pause>nul